package
{	
	import flash.display.BitmapData;
	import flash.geom.Point;
	import flash.display.Bitmap;
	import flash.events.Event;
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import flash.utils.Timer;
	import flash.events.TimerEvent;

	public class Main extends MovieClip
	{

		// タイマーオブジェクトを作成
		private var _timer:Timer;
		private var _screen:BitmapData;
		private var _bg:BitmapData;
		private var _drawPointList1:Vector.<DrawPoint>;
		private var _drawPointList2:Vector.<DrawPoint>;
		private var _drawPointList3:Vector.<DrawPoint>;
		private var _drawBMDList:Vector.<DrawBMD>;
		/////////////////////////////////////////////
		/**
		 * コンストラクタ.
		 * 
		 */
		
		public function Main()
		{
			_currentDrawPointNum = 0;
			_screen = new BitmapData(stage.stageWidth, stage.stageHeight, false, 0xFFFFFF);
			_bg = new BitmapData(stage.stageWidth, stage.stageHeight, false, 0xFFFFFF);

			_drawPointList1 = setTextBMList( new Txt1() );
			_drawPointList2 = setTextBMList( new Txt2() );
			_drawPointList3 = setTextBMList( new Txt3() );
			setBitmapDataList();

			addEventListener(Event.ENTER_FRAME, loop);

			this.addChild( new Bitmap(_screen) );

			_timer = new Timer(10000,0);
			_timer.addEventListener(TimerEvent.TIMER,function(e:TimerEvent):void{
				changePoint();
			});
			_timer.start();

			stage.addEventListener(MouseEvent.CLICK,function(){
				changePoint();
			});
		}

		private function setTextBMList( myTxt:BitmapData ):Vector.<DrawPoint>
		{
			var list:Vector.<DrawPoint> = new Vector.<DrawPoint>();
			var transRate:Point = new Point( (stage.stageWidth/2)-(myTxt.width/2), (stage.stageHeight/2)-(myTxt.height/2) )

			var len:int = myTxt.height
			for(var i:int =0; i<len; i++){
				var len2:int = myTxt.width;
				for(var i2:int =0; i2<len2; i2++){
					var colorP:int = myTxt.getPixel( i2, i );
					if(colorP != 16777215){
						var p:Point = new Point( transRate.x+i2, transRate.y+i );
						list.push( new DrawPoint( p ) );
					}
				}
			}
			return list;
		}
		private function setTextBMList2():void
		{
			_drawPointList2 = new Vector.<DrawPoint>();
			var myTxt:BitmapData = new Txt2();
			var transRate:Point = new Point( (stage.stageWidth/2)-(myTxt.width/2), (stage.stageHeight/2)-(myTxt.height/2) )
			var len:int = myTxt.height
			for(var i:int =0; i<len; i++){
				var len2:int = myTxt.width;
				for(var i2:int =0; i2<len2; i2++){
					var colorP:int = myTxt.getPixel( i2, i );
					if(colorP != 16777215){
						var p:Point = new Point( transRate.x+i2, transRate.y+i );
						_drawPointList2.push( new DrawPoint( p ) );
					}
				}
			}
		}

		private function setBitmapDataList():void
		{
			var color1:Number = 0xFF0000;
			var color2:Number = 0xFFCC00;
			var colorUnit:Number = color2-color1;
			_drawBMDList = new Vector.<DrawBMD>();
			var len:int = 8500;
			for(var i:int =0; i<len; i++){
				var sizeW:int = Math.floor(Math.random() * 2)+2;
				var sizeH:int = Math.floor(Math.random() * 2)+2;
				var color:Number = (Math.random() * colorUnit)+color1;
				var bmd:BitmapData = new BitmapData(sizeW, sizeH, false, color);
				var p:Point = _drawPointList1[ Math.floor(Math.random() * _drawPointList1.length) ].getPoint();
				_drawBMDList.push( new DrawBMD( bmd, p ) );
			}
		}

		private var _currentDrawPointNum:int
		private function changePoint():void
		{
			switch(_currentDrawPointNum){
				case 0: _currentDrawPointNum = 1;
					setAxisPoint( _drawPointList2 );
					break;
				case 1: _currentDrawPointNum = 2;
					setAxisPoint( _drawPointList3 );
					break;
				case 2: _currentDrawPointNum = 0;
					setAxisPoint( _drawPointList1 );
					break;
			}
		}


		private function setAxisPoint( list:Vector.<DrawPoint> ):void
		{
			var len:int = _drawBMDList.length
			for(var i:int =0; i<len; i++){
				var p:Point = list[ Math.floor(Math.random() * list.length) ].getPoint();
				_drawBMDList[ i ].setAxsisPoint( p );
			}
		}



		private function loop(e:Event):void
		{
			_screen.lock();
			_screen.copyPixels( _bg, _bg.rect, new Point(0, 0));
			var len:int = _drawBMDList.length
			for(var i:int =0; i<len; i++){
				var myDrawBMD:DrawBMD = _drawBMDList[ i ];
				myDrawBMD.update();
				var bmd:BitmapData = myDrawBMD.getBMD();
				var p:Point = myDrawBMD.getPoint();
				_screen.copyPixels( bmd, bmd.rect, p);
			}
			_screen.unlock();
		}



	}
}


/////////////////////////////////////////////
import flash.geom.Point;
import flash.display.BitmapData;
import org.libspark.betweenas3.BetweenAS3;
import org.libspark.betweenas3.tweens.ITween;
import org.libspark.betweenas3.events.TweenEvent;
import org.libspark.betweenas3.easing.Sine;
import org.libspark.betweenas3.easing.Linear;

class DrawPoint
{
    public var _axisPoint:Point;

	function DrawPoint( axisPoint:Point ):void
	{
		_axisPoint = axisPoint;
	}
	public function getPoint():Point
	{
		return _axisPoint
	}
	public function getPointX():int
	{
		return _axisPoint.x
	}
	public function getPointY():int
	{
		return _axisPoint.y
	}

}

class DrawBMD
{
	private var _tw:ITween;
	private var _axisPoint:Point;
    private var _currentPoint:Point;
	private var _bmd:BitmapData;
	private var _moveFlg:Boolean;
	private var _changeFlg:Boolean;

	function DrawBMD( bmd:BitmapData, axisPoint:Point ):void
	{
		_moveFlg = false;
		_changeFlg = false;
		_tw = null;
		_bmd = bmd;
		_axisPoint = axisPoint;
		_currentPoint = new Point( _axisPoint.x, _axisPoint.y );
	}

	public function update():void
	{
		if( _moveFlg != true )
		{
			var task:int = Math.floor(Math.random() * 7);
			if(task == 0){
				var t:int;
				if(_changeFlg == true){
					_changeFlg = false
					t = Math.floor(Math.random() * 20)+10;
				}else{
					t = Math.floor(Math.random() * 4)+3;
				}
				var p:Point = getTargetPosition(_axisPoint );
				_moveFlg = true;
				if(_tw != null){
					_tw.stop();
				}
				_tw = BetweenAS3.delay(BetweenAS3.tween(_currentPoint, { x:p.x, y:p.y }, null,t * 0.1 , Linear.linear), 0);
				_tw.removeEventListener(TweenEvent.COMPLETE, onCompleteHnadler);
				_tw.addEventListener(TweenEvent.COMPLETE, onCompleteHnadler);
				_tw.play();
				function onCompleteHnadler(e:TweenEvent):void
				{
					_tw.removeEventListener(TweenEvent.COMPLETE, onCompleteHnadler);
					_moveFlg = false;
				}
			}
		}
	}
	protected function getTargetPosition(axisP:Point):Point
	{
		var result:Point = new Point();

		var deg:Number = Math.floor(Math.random() * 360);
		var d:Number = Math.floor(Math.random() * 15);
	
		var rad:Number = deg * (Math.PI / 180);						
		var tempP:Point = Point.polar(d, rad);

		result.x = (axisP.x) + 5 + tempP.x;
		result.y = (axisP.y) + 5 + tempP.y;

		return result;
	}

	public function setAxsisPoint( axisP:Point ):void
	{
		_changeFlg = true;
		_axisPoint = axisP;
	}
	public function getBMD():BitmapData
	{
		return _bmd;
	}
	public function getPoint():Point
	{
		return _currentPoint;
	}
}